1с прочитать excel веб клиент

 0 

Во время реализации задачи по регистрации продаж дистрибьюторов на основании Excel документов столкнулся с интересной задачей. Необходимо реализовать загрузку файла и на стороне сервера обработать его, заполнив табличную часть документа.

Решение состоит из двух функций: клиентской и серверной.

Клиентская часть инициирует выбор файла, передачу выбранного файла на сервер и передача управления серверной процедуре.

Код 1C v 8.2 УП

 #НаКлиенте

Процедура ИмпортИзВнешнегоФайла(Команда)

     //Выбор и загрузка файла.

     Если НЕ  ПодключитьРасширениеРаботыСФайлами() Тогда

          УстановитьРасширениеРаботыСФайлами();

     КонецЕсли;

 
     Если  ПодключитьРасширениеРаботыСФайлами() Тогда

          Режим =  РежимДиалогаВыбораФайла.Открытие;

          ДиалогОткрытияФайла = Новый  ДиалогВыбораФайла(Режим);

          ДиалогОткрытияФайла.ПолноеИмяФайла = "";

          ДиалогОткрытияФайла.МножественныйВыбор = Ложь;

          Фильтр = "Текст(*.xls)|*.xls";

          ДиалогОткрытияФайла.Фильтр = Фильтр;

          ДиалогОткрытияФайла.Заголовок = "Выберите файл для импорта";

          Если  ДиалогОткрытияФайла.Выбрать() Тогда

               Объект.МедицинскиеРаботники.Очистить();

               ДанныеНачинаютсяС = 1;

              Если  Не ВвестиЧисло(ДанныеНачинаютсяС, "Данные начинаются со строки", 2,  0) Тогда

                    Возврат;

              КонецЕсли;

              МассивФайлов = ДиалогОткрытияФайла.ВыбранныеФайлы;

              ПомещаемыеФайлы = Новый Массив;

              Для  Каждого Файл Из МассивФайлов Цикл

                   ТекФайл = Новый Файл(Файл);

                   Описание = Новый ОписаниеПередаваемогоФайла(Файл, "");

                   ПомещаемыеФайлы.Добавить(Описание);

              КонецЦикла;

 
              ПомещенныеФайлы = Новый Массив;

 
              Если  ПоместитьФайлы(ПомещаемыеФайлы, ПомещенныеФайлы, , Ложь, УникальныйИдентификатор) Тогда

                   //Запуск импорта

                   ИмпортироватьФайлИзВременногоХранилищаВТЗ(ПомещенныеФайлы, ДанныеНачинаютсяС);

              КонецЕсли;

         Иначе

              Предупреждение("Файл(ы) не  выбран!");

         КонецЕсли;

     Иначе

          Предупреждение(НСтр("ru ='Данная возможность недоступна, так как не подключено расширение работы с файлами.'", "ru"));

     КонецЕсли;

КонецПроцедуры //ИмпортИзВнешнегоФайла()   

Серверная процедура перебирает полученные на сервер файлы. Получает COM-объекты и импортирует данные.

Код 1C v 8.2 УП

 #НаСервере

Процедура ИмпортироватьФайлИзВременногоХранилищаВТЗ(МассивФайлов,  ДанныеНачинаютсяС)

    ДокументОбъект =  РеквизитФормыВЗначение("Объект");

 
    //Обход файлов, записанных  во временное хранилище

    Для Каждого  ЭлементМассива Из МассивФайлов Цикл

        ФайлИзХранилища =  ПолучитьИзВременногоХранилища(ЭлементМассива.Хранение);

        ВременныйФайл = ПолучитьИмяВременногоФайла("xls");

       //Сохранение во временнный файл на диске

       ФайлИзХранилища.Записать(ВременныйФайл);

 
       //Импорт

       Док =  ПолучитьCOMОбъект(ВременныйФайл);

       ФИОУчастника = Док.Sheets(1).Cells(ДанныеНачинаютсяС, 2).Value;

       Пока СокрЛП(ФИОУчастника) ="" Цикл

           //  Добавление строки с файла в документ

          НоваяСтрока = ДокументОбъект.МедицинскиеРаботники.Добавить();

          НоваяСтрока.Фио = ФИОУчастника;

          НоваяСтрока.Учреждение = Док.Sheets(1).Cells(ДанныеНачинаютсяС, 7).Value;

          НоваяСтрока.Адрес = Док.Sheets(1).Cells(ДанныеНачинаютсяС, 3).Value;

          НоваяСтрока.Телефон = Док.Sheets(1).Cells(ДанныеНачинаютсяС, 4).Value;

          НоваяСтрока.ЭлПочта = Док.Sheets(1).Cells(ДанныеНачинаютсяС, 5).Value;

          НоваяСтрока.Образование = Док.Sheets(1).Cells(ДанныеНачинаютсяС, 6).Value;

          ДанныеНачинаютсяС = ДанныеНачинаютсяС + 1;

          ФИОУчастника = Док.Sheets(1).Cells(ДанныеНачинаютсяС, 2).Value;

      КонецЦикла;

      Сообщить("Импорт завершён");

      Док.Application.Quit();

    КонецЦикла;

    ЗначениеВРеквизитФормы(ДокументОбъект, "Объект");

КонецПроцедуры  //ИмпортироватьФайлИзВременногоХранилищаВТЗ()   

Источник

Есть такой вопрос. Необходимо создать многостраничный файл excel.

Ньюанс, что это необходимо на вебклиенте.

Насколько это реализуемо?

В толстом клиенте без вопросов все работает.

Алгоритм таков:

-делаю несколько файлов в excel;

-потом их читаю и добавляю в один;

На вебклиенте проблемы такие:

-1.Всплывающие окна при первом проходе сохранения файлов.

ПолучитьФайл(АдресХранилища, ИмяФайла, Истина);

-2.Этап Как это можно сделать навебклиенте.

Рабочий код толстого клиента

    Попытка

        ДокЭксель = Новый COMОбъект(«Excel.Application»);

        ДокЭксель.DisplayAlerts=Ложь;

        ДокЭксель.visible = Ложь;

        ОбщаяКнига= ДокЭксель.WorkBooks.Add();

    Исключение

        Сообщить(«Ошибка. Возможно неверно указан номер листа книги Excel.»);

        Возврат ;

    КонецПопытки;

    УдалитьФайлы(Отчет.КаталогСохранения+»statistics.xls»);

    Попытка

        ОбщаяКнига.SaveAs(КаталогВременныхФайлов()+»statistics.xls»);

    Исключение

        Сообщить(ОписаниеОшибки()+» Файл не сохранен!»);

    КонецПопытки;

    ОбщаяКнига.close();

    
    ОбщаяКнига2=ДокЭксель.WorkBooks.Open(КаталогВременныхФайлов()+»statistics.xls»);

    Первый      = истина;

    ПрошлыйЛист = Неопределено;

    МассивПутейФайловXLS = НайтиФайлы(Отчет.РабочийКаталог,»*.xls»,Ложь);

    Для каждого ПутьКФайлуXLS Из МассивПутейФайловXLS Цикл

        ИмяЛиста=»»;

        Если ПутьКФайлуXLS.ИмяБезРасширения=»Итоговая» Тогда

            ИмяЛиста = «Total»;

        Иначе

            Продолжить;

        КонецЕсли;    

        Книга            = ДокЭксель.WorkBooks.Open(ПутьКФайлуXLS.ПолноеИмя);

        Книга.Worksheets(1).Cells.Select();

        ДокЭксель.Selection.Copy();

        Если Первый Тогда

            НовыйЛист =  ОбщаяКнига2.Worksheets(1);

            Первый = Ложь;

        Иначе    

            НовыйЛист = ОбщаяКнига2.Worksheets.Add(,ПрошлыйЛист);

        КонецЕсли;

        НовыйЛист.Paste();

        НовыйЛист.Activate();

        НовыйЛист.Name=ИмяЛиста;

        ДокЭксель.Range(«A1»).Select();

        ПрошлыйЛист = НовыйЛист;

        Книга.Close();

    КонецЦикла;

    ОбщаяКнига2.close();

    ДокЭксель.Quit();

    ДокЭксель = Неопределено;

(0) 1. На веб-клиенте требуется чтобы стоял плагин в браузере «Расширение для работы с 1С:Предприятием»

2. Нафик это делать на клиенте? На сервере делай.

Сейчас вопрос про comобъект.

Почему наклиенте comобъект отрабатывает, а на вебклиенте выдает ошибку отказано в доступе?

Какого ему доступа не хватает?

В вебклиенте через сервер обращаюсь к com

&НаСервере

Функция  ПоключитьсяКExcel(ИмяФайла)

    //ИмяФайла = Полный путь к файлу Excel

    Соотв = Новый Соответствие;

    Попытка

        Листы = Новый Массив;

        Excel = Новый COMОбъект(«Excel.Application»);//выбивает с ошибкой :ошибка при вызове конструктора() — отказано в доступе

        …

    Исключение

        Сообщить(«Ошибка создания обьекта Microsoft Excel» + ОписаниеОшибки());

        лРезультат = Неопределено;

    КонецПопытки;

    
    Возврат лРезультат;

КонецФункции

на клиенте без веба все работает

…

Попытка

        ДокЭксель = Новый COMОбъект(«Excel.Application»);

        ДокЭксель.DisplayAlerts=Ложь;

        ДокЭксель.visible = Ложь;

        ОбщаяКнига= ДокЭксель.WorkBooks.Add();

    Исключение

        Сообщить(«Ошибка. Возможно неверно указан номер листа книги Excel.»);

        Возврат ;

    КонецПопытки;

…

Сияющий в темноте

9 — 24.04.20 — 23:06

Весьма частая задача, с которой сталкивается 1С разработчик – это чтение файлов Excel и загрузка их в 1С. Есть как минимум два способа прочитать файл Excel – средствами платформы 1С, или используя COM-объект приложения MS Excel. В статье рассматривается чтение файлов xls, xlsx при помощи табличного документа.

Содержание

Общая информация

В платформе 1С 8 существует объект ТабличныйДокумент, который позволяет формировать и выводить на экран печатные формы в табличном виде. Но у табличного документа есть еще одно применение – чтение данных из табличных файлов. Поддерживаются форматы xls, xlsx и ods. Т.е. можно загружать табличные файлы, созданные в пакете MS Office или OpenOffice Calc.

Значения типа Число или Дата, содержащиеся в ячейках исходного табличного файла, можно считать двумя способами – как значение, либо как текст. Рассмотрим пример: пусть в ячейке содержится число 123,456, и установлен формат с округлением до целого числа; в этом случае отображаться будет текст “123”, а значение будет храниться 123,456

1. Если прочитать с указанием способа чтения как “Значение”, в табличный документ 1С будет прочитано исходное значение 123,456
2. Если прочитать с указанием способа чтения как “Текст”, значение будет потеряно, и в табличный документ прочитается текст “123”

Использование объекта ВременноеХранилище

Вспомогательные процедуры — диалог выбора файла

Следующий код не является обязательным для решения задачи – путь к исходному файлу можно указать в коде, ввести вручную, скопировать из адресной строки ОС или прочитать из БД – вариантов очень много. Мы же рассмотрим пример, когда пользователь сам указывает файл на клиентском компьютере, и путь к этому файлу помещается в реквизит. В примере будем использовать реквизит формы ПутьКФайлу

Создадим обработчик события НачалоВыбора:

&НаКлиенте
Процедура ПутьКФайлуНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)
	
	СтандартнаяОбработка = Ложь;
	ВыбратьФайлНаКлиенте();
	
КонецПроцедуры

Для того чтобы код был универсальным, и работал в случае отказа от модальных синхронных методов, нам понадобится создать асинхронную процедуру ВыбратьФайлНаКлиенте(). В ней мы создаем диалог выбора для открытия файла, указываем фильтр с нужными форматами – xls и xlsx, а также отключаем множественный выбор файлов. Перед методом ВыбратьАсинх добавляем ключевое слово Ждать, с тем чтобы дальнейший код дождался возвращаемого значения.

&НаКлиенте
Асинх Процедура ВыбратьФайлНаКлиенте()
	
	Перем Диалог;
	
	Диалог = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Открытие);
	Диалог.Фильтр = "Excel файлы(*.xls;*.xlsx)|*.xls;*.xlsx";
	Диалог.ИндексФильтра = 0;
	Диалог.ПредварительныйПросмотр = Ложь;
	Диалог.МножественныйВыбор = Ложь; 
	РезультатВыбора = Ждать Диалог.ВыбратьАсинх();
	Если РезультатВыбора <> Неопределено Тогда
		ПутьКФайлу = РезультатВыбора[0];
	КонецЕсли;
	
КонецПроцедуры

Двоичные данные во временное хранилище

Логика кода будет следующая. Нам понадобятся двепроцедуры – клиентский обработчик команды, и серверный метод который и будет непосредственно считывать переданный файл.

Клиентский код:

1. проверяем, указан ли путь к файлу. Если не указан – прекращаем выполнение
2. Получаем двоичные данные из файла по указанному пути
3. Помещаем эти двоичные данные во временное хранилище
4. Далее передаем на сервер адрес этого временного хранилища

&НаКлиенте
Процедура ДвоичныеДанныеВоВременноеХранилище(Команда)

	Если Не ЗначениеЗаполнено(ПутьКФайлу) Тогда
		Возврат;
	КонецЕсли;
	
	ДД = Новый ДвоичныеДанные(ПутьКФайлу);
	АдресВХ = ПоместитьВоВременноеХранилище(ДД);
	ПрочитатьИзВХНаСервере(АдресВХ);
	
КонецПроцедуры

Серверный код:

1. Создаем временный файл с нужным расширением (в примере – xlsx)
2. Получаем двоичные данные из временного хранилища
3. Записываем во временный файл
4. Определяем вариант чтения файла – читать значения табличного документа как текст, или как значения
5. Далее используем метод Прочитать, и считываем из временного файла данные в табличный документ

Метод Прочитать лучше делать в попытке, и отдельно продумать и написать код обработки исключения. для упрощения примера мы это исключение никак не обрабатываем. В случае, если передан поврежденный файл, или его невозможно прочитать по какой-то другой причине, он просто не считается в табличный документ.

&НаСервере
Процедура ПрочитатьИзВХНаСервере(АдресВХ, Режим = "Значение")
	
	ИмяВременногоФайла = ПолучитьИмяВременногоФайла("xlsx");
	
	ДД = ПолучитьИзВременногоХранилища(АдресВХ);
	ДД.Записать(ИмяВременногоФайла);

	Если Режим = "Текст" Тогда
		СпособЧтения = СпособЧтенияЗначенийТабличногоДокумента.Текст;
	Иначе
		СпособЧтения = СпособЧтенияЗначенийТабличногоДокумента.Значение;
	КонецЕсли;

	Попытка
		ТабДок.Прочитать(ИмяВременногоФайла, СпособЧтения);
	Исключение
	КонецПопытки;	
	
КонецПроцедуры

Рассмотренный пример является достаточно универсальным – процедуру ПрочитатьИзВХНаСервере() можно использовать с любыми двоичными данными, помещенными во временное хранилище. Это могут быть двоичные данные, полученные с веб-сервиса, считанные из базы данных, полученные из макета, созданного в конфигураторе – код от этого не изменится.

Помещение файла на сервер в 1С

Более простой, но менее универсальный способ, предназначенный исключительно для передачи файла с клиента на сервер – это использование метода НачатьПомещениеФайлаНаСервер. В платформе предусмотрено несколько методов для помещения файлов – как одиночных, так и нескольких одновременно. Эти методы делятся на синхронные и асинхронные. Начиная с версии 8.3.18 появились методы, использующие ключевые слова Асинх и Ждать. Аналогичный метод мы рассмотрели при работе с диалогом. Далее разберем “классический” вариант с обработкой оповещения. 

Логика кода следующая:

1. Создаем описание оповещения и указываем в нем процедуру, которая будет вызвана после окончания помещения файла на сервер
2. Указываем параметры диалога выбора файла и добавляем фильтр
3. Вызываем помещение файла на сервер
4. После того как файл помещен во временное хранилище, используем ту же процедуру, которую мы реализовали в первом примере – ПрочитатьИзВХНаСервере. В этом примере мы для разнообразия используем способ чтения значений как “Текст”.

&НаКлиенте
Процедура ПередачаФайла(Команда)
	
ОбработкаОкончанияПомещения = Новый ОписаниеОповещения("ОбработчикОкончанияПомещения", ЭтотОбъект);
ПараметрыДиалога = Новый ПараметрыДиалогаПомещенияФайлов;
ПараметрыДиалога.Фильтр = "Excel файлы(*.xls;*.xlsx)|*.xls;*.xlsx";
НачатьПомещениеФайлаНаСервер(ОбработкаОкончанияПомещения, , , АдресВХ, ПараметрыДиалога, ЭтотОбъект.УникальныйИдентификатор);
	
КонецПроцедуры

&НаКлиенте
Процедура ОбработчикОкончанияПомещения(ОписаниеПомещенногоФайла, ДополнительныеПараметры) Экспорт
	
АдресФайла = ОписаниеПомещенногоФайла.Адрес;
ПрочитатьИзВХНаСервере(АдресФайла, "Текст");
	
КонецПроцедуры

Использование потока для чтения файла

В случае, если нам нужно просто передать файл с клиента на сервер для сохранения в базу данных, либо мы хотим прочитать файл в формате ods(Open Documents Spreadsheet) или mxl(встроенный формат табличных документов 1С), мы можем воспользоваться еще одним способом – с использованием потоков данных.

В этом случае нам не понадобится создавать временный файл и следить за его корректным удалением. Код будет очень похож на прерыдущий пример. Мы также выбираем файл с использованием метода НачатьПомещениеФайлаНаСервер, но указываем другой фильтр. А в обработчике оповещения вызываем серверную процедуру ПрочитатьВПоток. В методе Прочитать() нам нужно явным образом указать тип файла табличного документа, который мы считываем.

&НаКлиенте
Процедура ПрочитатьЧерезПоток(Команда)

ОбработкаОкончанияПомещения = Новый ОписаниеОповещения("ОбработчикОкончанияПомещенияПоток", ЭтотОбъект);
ПараметрыДиалога = Новый ПараметрыДиалогаПомещенияФайлов;
ПараметрыДиалога.Фильтр = "файлы ODS или MXL|*.ods;*.mxl";

НачатьПомещениеФайлаНаСервер(ОбработкаОкончанияПомещения, , , АдресВХ, ПараметрыДиалога, ЭтотОбъект.УникальныйИдентификатор);

КонецПроцедуры

&НаКлиенте
Процедура ОбработчикОкончанияПомещенияПоток(ОписаниеПомещенногоФайла, ДополнительныеПараметры) Экспорт

АдресФайла = ОписаниеПомещенногоФайла.Адрес;
ПрочитатьВПоток(АдресФайла);

КонецПроцедуры

&НаСервере
Процедура ПрочитатьВПоток(АдресФайла)

ДД = ПолучитьИзВременногоХранилища(АдресФайла);
Поток = ДД.ОткрытьПотокДляЧтения();
ТабДок.Прочитать(Поток,,ТипФайлаТабличногоДокумента.ODS);
Поток.Закрыть();

КонецПроцедуры

Надеюсь, рассмотренные примеры помогут вам справиться с задачей передать файл с клиента на сервере и прочитать файл Excel в 1С.