1с чтение файла excel на сервере

Весьма частая задача, с которой сталкивается 1С разработчик – это чтение файлов Excel и загрузка их в 1С. Есть как минимум два способа прочитать файл Excel – средствами платформы 1С, или используя COM-объект приложения MS Excel. В статье рассматривается чтение файлов xls, xlsx при помощи табличного документа.

Содержание

Общая информация

В платформе 1С 8 существует объект ТабличныйДокумент, который позволяет формировать и выводить на экран печатные формы в табличном виде. Но у табличного документа есть еще одно применение – чтение данных из табличных файлов. Поддерживаются форматы xls, xlsx и ods. Т.е. можно загружать табличные файлы, созданные в пакете MS Office или OpenOffice Calc.

Значения типа Число или Дата, содержащиеся в ячейках исходного табличного файла, можно считать двумя способами – как значение, либо как текст. Рассмотрим пример: пусть в ячейке содержится число 123,456, и установлен формат с округлением до целого числа; в этом случае отображаться будет текст “123”, а значение будет храниться 123,456

1. Если прочитать с указанием способа чтения как “Значение”, в табличный документ 1С будет прочитано исходное значение 123,456
2. Если прочитать с указанием способа чтения как “Текст”, значение будет потеряно, и в табличный документ прочитается текст “123”

Использование объекта ВременноеХранилище

Вспомогательные процедуры — диалог выбора файла

Следующий код не является обязательным для решения задачи – путь к исходному файлу можно указать в коде, ввести вручную, скопировать из адресной строки ОС или прочитать из БД – вариантов очень много. Мы же рассмотрим пример, когда пользователь сам указывает файл на клиентском компьютере, и путь к этому файлу помещается в реквизит. В примере будем использовать реквизит формы ПутьКФайлу

Создадим обработчик события НачалоВыбора:

&НаКлиенте
Процедура ПутьКФайлуНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)
	
	СтандартнаяОбработка = Ложь;
	ВыбратьФайлНаКлиенте();
	
КонецПроцедуры

Для того чтобы код был универсальным, и работал в случае отказа от модальных синхронных методов, нам понадобится создать асинхронную процедуру ВыбратьФайлНаКлиенте(). В ней мы создаем диалог выбора для открытия файла, указываем фильтр с нужными форматами – xls и xlsx, а также отключаем множественный выбор файлов. Перед методом ВыбратьАсинх добавляем ключевое слово Ждать, с тем чтобы дальнейший код дождался возвращаемого значения.

&НаКлиенте
Асинх Процедура ВыбратьФайлНаКлиенте()
	
	Перем Диалог;
	
	Диалог = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Открытие);
	Диалог.Фильтр = "Excel файлы(*.xls;*.xlsx)|*.xls;*.xlsx";
	Диалог.ИндексФильтра = 0;
	Диалог.ПредварительныйПросмотр = Ложь;
	Диалог.МножественныйВыбор = Ложь; 
	РезультатВыбора = Ждать Диалог.ВыбратьАсинх();
	Если РезультатВыбора <> Неопределено Тогда
		ПутьКФайлу = РезультатВыбора[0];
	КонецЕсли;
	
КонецПроцедуры

Двоичные данные во временное хранилище

Логика кода будет следующая. Нам понадобятся двепроцедуры – клиентский обработчик команды, и серверный метод который и будет непосредственно считывать переданный файл.

Клиентский код:

1. проверяем, указан ли путь к файлу. Если не указан – прекращаем выполнение
2. Получаем двоичные данные из файла по указанному пути
3. Помещаем эти двоичные данные во временное хранилище
4. Далее передаем на сервер адрес этого временного хранилища

&НаКлиенте
Процедура ДвоичныеДанныеВоВременноеХранилище(Команда)

	Если Не ЗначениеЗаполнено(ПутьКФайлу) Тогда
		Возврат;
	КонецЕсли;
	
	ДД = Новый ДвоичныеДанные(ПутьКФайлу);
	АдресВХ = ПоместитьВоВременноеХранилище(ДД);
	ПрочитатьИзВХНаСервере(АдресВХ);
	
КонецПроцедуры

Серверный код:

1. Создаем временный файл с нужным расширением (в примере – xlsx)
2. Получаем двоичные данные из временного хранилища
3. Записываем во временный файл
4. Определяем вариант чтения файла – читать значения табличного документа как текст, или как значения
5. Далее используем метод Прочитать, и считываем из временного файла данные в табличный документ

Метод Прочитать лучше делать в попытке, и отдельно продумать и написать код обработки исключения. для упрощения примера мы это исключение никак не обрабатываем. В случае, если передан поврежденный файл, или его невозможно прочитать по какой-то другой причине, он просто не считается в табличный документ.

&НаСервере
Процедура ПрочитатьИзВХНаСервере(АдресВХ, Режим = "Значение")
	
	ИмяВременногоФайла = ПолучитьИмяВременногоФайла("xlsx");
	
	ДД = ПолучитьИзВременногоХранилища(АдресВХ);
	ДД.Записать(ИмяВременногоФайла);

	Если Режим = "Текст" Тогда
		СпособЧтения = СпособЧтенияЗначенийТабличногоДокумента.Текст;
	Иначе
		СпособЧтения = СпособЧтенияЗначенийТабличногоДокумента.Значение;
	КонецЕсли;

	Попытка
		ТабДок.Прочитать(ИмяВременногоФайла, СпособЧтения);
	Исключение
	КонецПопытки;	
	
КонецПроцедуры

Рассмотренный пример является достаточно универсальным – процедуру ПрочитатьИзВХНаСервере() можно использовать с любыми двоичными данными, помещенными во временное хранилище. Это могут быть двоичные данные, полученные с веб-сервиса, считанные из базы данных, полученные из макета, созданного в конфигураторе – код от этого не изменится.

Помещение файла на сервер в 1С

Более простой, но менее универсальный способ, предназначенный исключительно для передачи файла с клиента на сервер – это использование метода НачатьПомещениеФайлаНаСервер. В платформе предусмотрено несколько методов для помещения файлов – как одиночных, так и нескольких одновременно. Эти методы делятся на синхронные и асинхронные. Начиная с версии 8.3.18 появились методы, использующие ключевые слова Асинх и Ждать. Аналогичный метод мы рассмотрели при работе с диалогом. Далее разберем “классический” вариант с обработкой оповещения. 

Логика кода следующая:

1. Создаем описание оповещения и указываем в нем процедуру, которая будет вызвана после окончания помещения файла на сервер
2. Указываем параметры диалога выбора файла и добавляем фильтр
3. Вызываем помещение файла на сервер
4. После того как файл помещен во временное хранилище, используем ту же процедуру, которую мы реализовали в первом примере – ПрочитатьИзВХНаСервере. В этом примере мы для разнообразия используем способ чтения значений как “Текст”.

&НаКлиенте
Процедура ПередачаФайла(Команда)
	
ОбработкаОкончанияПомещения = Новый ОписаниеОповещения("ОбработчикОкончанияПомещения", ЭтотОбъект);
ПараметрыДиалога = Новый ПараметрыДиалогаПомещенияФайлов;
ПараметрыДиалога.Фильтр = "Excel файлы(*.xls;*.xlsx)|*.xls;*.xlsx";
НачатьПомещениеФайлаНаСервер(ОбработкаОкончанияПомещения, , , АдресВХ, ПараметрыДиалога, ЭтотОбъект.УникальныйИдентификатор);
	
КонецПроцедуры

&НаКлиенте
Процедура ОбработчикОкончанияПомещения(ОписаниеПомещенногоФайла, ДополнительныеПараметры) Экспорт
	
АдресФайла = ОписаниеПомещенногоФайла.Адрес;
ПрочитатьИзВХНаСервере(АдресФайла, "Текст");
	
КонецПроцедуры

Использование потока для чтения файла

В случае, если нам нужно просто передать файл с клиента на сервер для сохранения в базу данных, либо мы хотим прочитать файл в формате ods(Open Documents Spreadsheet) или mxl(встроенный формат табличных документов 1С), мы можем воспользоваться еще одним способом – с использованием потоков данных.

В этом случае нам не понадобится создавать временный файл и следить за его корректным удалением. Код будет очень похож на прерыдущий пример. Мы также выбираем файл с использованием метода НачатьПомещениеФайлаНаСервер, но указываем другой фильтр. А в обработчике оповещения вызываем серверную процедуру ПрочитатьВПоток. В методе Прочитать() нам нужно явным образом указать тип файла табличного документа, который мы считываем.

&НаКлиенте
Процедура ПрочитатьЧерезПоток(Команда)

ОбработкаОкончанияПомещения = Новый ОписаниеОповещения("ОбработчикОкончанияПомещенияПоток", ЭтотОбъект);
ПараметрыДиалога = Новый ПараметрыДиалогаПомещенияФайлов;
ПараметрыДиалога.Фильтр = "файлы ODS или MXL|*.ods;*.mxl";

НачатьПомещениеФайлаНаСервер(ОбработкаОкончанияПомещения, , , АдресВХ, ПараметрыДиалога, ЭтотОбъект.УникальныйИдентификатор);

КонецПроцедуры

&НаКлиенте
Процедура ОбработчикОкончанияПомещенияПоток(ОписаниеПомещенногоФайла, ДополнительныеПараметры) Экспорт

АдресФайла = ОписаниеПомещенногоФайла.Адрес;
ПрочитатьВПоток(АдресФайла);

КонецПроцедуры

&НаСервере
Процедура ПрочитатьВПоток(АдресФайла)

ДД = ПолучитьИзВременногоХранилища(АдресФайла);
Поток = ДД.ОткрытьПотокДляЧтения();
ТабДок.Прочитать(Поток,,ТипФайлаТабличногоДокумента.ODS);
Поток.Закрыть();

КонецПроцедуры

Надеюсь, рассмотренные примеры помогут вам справиться с задачей передать файл с клиента на сервере и прочитать файл Excel в 1С.

Здравствуйте! Подскажите что может быть, ситуация следующая.

Есть сервер, на нем крутится 1С.

Есть база в которую идет загрузка из 1С(КС вариант).

Так вот при передачи фала EXCEL с клиента на сервер происходит сохранение данного файла в определенной папке(в контексте сервера), потом так же в контексте сервера происходит попытка открытия этого файла — но вылетает ошибка :

————————————————-

{Документ.КонкурсПоУслугам.Форма.ФормаЗагрузкиИзEXCEL.Форма(36)}: Ошибка при вызове метода контекста (Open)

   Книга = Эксель.WorkBooks.Open(ИмяФайла);

по причине:

Произошла исключительная ситуация (Microsoft Excel): Приложению Microsoft Excel не удается получить доступ к файлу «G:1C_TempШахматка_08_11_2012_02_06_32.xlsx». Это может быть вызвано одной из следующих причин.

• Указан несуществующий файл или путь.

• Файл используется другой программой.

• Имя книги, которую вы пытаетесь сохранить, совпадает с именем другой книги, открытой в данный момент.

————————————————-

Код который все это делает ниже:

————————————————-

//2. Получим файлик для загрузки из временного хранилища

   ИмяФайла = «G:1C_TempШахматка_»+Формат(ТекущаяДата(),»ДФ=dd_MM_yyyy_hh_mm_ss»)+».xlsx»;//Сисадмины сказали что в темпе хранит не феншуйно и выделили отдельную папку    

   Файлик   = ПолучитьИзВременногоХранилища(АдресВовременномХранилище);

   Файлик.Записать(ИмяФайла);          

   
   //3. Попробуем открыть EXCEL          

   Попытка        Эксель = Новый COMОбъект(«Excel.Application»);

   Исключение    Сообщить(ОписаниеОшибки()); УдалитьФайлы(ИмяФайла); Возврат Неопределено;

   КонецПопытки;

————————————————-

Перед открытием файлика, в режиме отладки, проверял — он существует(ФС.Существует()). Другой программой он не используется так как создается. у пользователя под которым выполняется код на стороне сервера разрешение на чтение/запись файла есть.

Что может быть, куда копать?

выложил не весь код.Вот весь:

//2. Получим файлик для загрузки из временного хранилища

   ИмяФайла = «G:1C_TempШахматка_»+Формат(ТекущаяДата(),»ДФ=dd_MM_yyyy_hh_mm_ss»)+».xlsx»;//Сисадмины сказали что в темпе хранит не феншуйно и выделили отдельную папку    

   Файлик   = ПолучитьИзВременногоХранилища(АдресВовременномХранилище);

   Файлик.Записать(ИмяФайла);          

   
   //3. Попробуем открыть EXCEL          

   Попытка        Эксель = Новый COMОбъект(«Excel.Application»);

   Исключение    Сообщить(ОписаниеОшибки()); УдалитьФайлы(ИмяФайла); Возврат Неопределено;

   КонецПопытки;

   
   //4. Откроем файлик и книгу

   Книга = Эксель.WorkBooks.Open(ИмяФайла);

   Лист  = Книга.WorkSheets(НомерЛиста);

(1) если бы.Ставил точку останова на

Книга = Эксель.WorkBooks.Open(ИмяФайла);

находил этот файлик по ИмяФайла, открывал его, закрывал и продолжал откладку.Все равно куй.

Вызов на стороне клиента:

&НаКлиенте

Процедура Загрузить(Команда)

   
   //1. Поместим наш файлик во временное хранилище

   Перем АдресВовременномХранилище;

   Если Не ЗначениеЗаполнено(Файл) Тогда Возврат; КонецЕсли;

   ПоместитьФайл(АдресВовременномХранилище, Файл, , Ложь);

   
   //2. Произведем чтение и разбор этого файла

   Адрес = ПроизвестиЧтениеГоризонтальнойШахматки(АдресВовременномХранилище);    

   
   //3. Оповестим о том что все сделано

   Если ЭтоАдресВременногоХранилища(Адрес) Тогда

       ОповеститьОВыборе(Новый Структура(«ДанныеЗагрузки», Адрес));

   Иначе

       ЭтаФорма.Закрыть();

   КонецЕсли;

КонецПроцедуры

Вызов на стороне сервера:

&НаСервере

Функция ПроизвестиЧтениеГоризонтальнойШахматки(АдресВовременномХранилище)

   
   //1. Сформируем табличку в которую будем загружать

   тзУслуги = Новый ТаблицаЗначений;

   тзУслуги.Колонки.Добавить(«Лот»             , Новый ОписаниеТипов(«СправочникСсылка.Объекты»));

   тзУслуги.Колонки.Добавить(«Услуга»          , Новый ОписаниеТипов(«СправочникСсылка.Объекты»));

   тзУслуги.Колонки.Добавить(«Марка»           , Новый ОписаниеТипов(«Строка»));

   тзУслуги.Колонки.Добавить(«ЕдиницаИзмерения», Новый ОписаниеТипов(«СправочникСсылка.ЕдиницыИзмерения»));

   тзУслуги.Колонки.Добавить(«Количество»      , Новый ОписаниеТипов(«Число»));

   тзУслуги.Колонки.Добавить(«ПДЦБезНДС»       , Новый ОписаниеТипов(«Число»));

   тзУслуги.Колонки.Добавить(«ПДЦ»             , Новый ОписаниеТипов(«Число»));

   тзУслуги.Колонки.Добавить(«Дорога»          , Новый ОписаниеТипов(«СправочникСсылка.Дороги»));

   тзУслуги.Колонки.Добавить(«УчастникКонкурса», Новый ОписаниеТипов(«СправочникСсылка.Организации»));

   тзУслуги.Колонки.Добавить(«ФКП»             , Новый ОписаниеТипов(«Число»));

   тзУслуги.Колонки.Добавить(«ФКП_БезНДС»      , Новый ОписаниеТипов(«Число»));

   
   //2. Получим файлик для загрузки из временного хранилища

   //ИмяФайла = «G:1C_TempШахматка_»+Формат(ТекущаяДата(),»ДФ=dd_MM_yyyy_hh_mm_ss»)+».xlsx»;//Сисадмины сказали что в темпе хранит не феншуйно и выделили отдельную папку    

   ИмяФайла = «G:1С ОбработкиШахматка.xlsx»;

   Файлик   = ПолучитьИзВременногоХранилища(АдресВовременномХранилище);

   Файлик.Записать(ИмяФайла);

   Файлик = «»;

   
   //3. Попробуем открыть EXCEL          

   Попытка        Эксель = Новый COMОбъект(«Excel.Application»);

   Исключение    Сообщить(ОписаниеОшибки()); УдалитьФайлы(ИмяФайла); Возврат Неопределено;

   КонецПопытки;

   
   //4. Откроем файлик и книгу

   Книга = Эксель.WorkBooks.Open(ИмяФайла);

   Лист  = Книга.WorkSheets(НомерЛиста);

   
   //5. Получим количество колонок и строк

   ВсегоКолонок = Лист.Cells(1,1).SpecialCells(11).Column;

   ВсегоСтрок   = Лист.Cells(1,1).SpecialCells(11).Row;

   
   //Далше всякая ерунда, она не нужна что бы глаз не мозолить

КонецФункции

>>> «У пользователя под которым выполняются серверные процедуры»

Ну все… если у вас голубчик стоит серверная версия 8-ки, то то-что выполняется на сервере, выполняется под серверным пользователем «Локальным относительно сервера».

А вообще, телепат устал, так что…

(30) я всё-таки за (1) Поэтому лучше так

     
   //3. Попробуем открыть EXCEL          

   Попытка        Эксель = Новый COMОбъект(«Excel.Application»);

   Исключение    Сообщить(ОписаниеОшибки()); УдалитьФайлы(ИмяФайла); Возврат Неопределено;

   КонецПопытки;

Файлик   = ПолучитьИзВременногоХранилища(АдресВовременномХранилище);

   Файлик.Записать(ИмяФайла);

(33) сделал даже так:

//3. Попробуем открыть EXCEL          

   Попытка        Эксель = Новый COMОбъект(«Excel.Application»);

   Исключение    Сообщить(ОписаниеОшибки());

       //УдалитьФайлы(ИмяФайла);

       Эксель = Неопределено;

       Возврат Неопределено;

   КонецПопытки;

   
   НачальноеВремя = ТекущаяДата();    

   Пока ТекущаяДата()< НачальноеВремя + 5 Цикл КонецЦикла;

   
   //2. Получим файлик для загрузки из временного хранилища

   ИмяФайла = «G:1C_TempШахматка_»+Формат(ТекущаяДата(),»ДФ=dd_MM_yyyy_hh_mm_ss»)+».xlsx»;//Сисадмины сказали что в темпе хранит не феншуйно и выделили отдельную папку        

   Файлик   = ПолучитьИзВременногоХранилища(АдресВовременномХранилище);

   Файлик.Записать(ИмяФайла);

   
   //4. Откроем файлик и книгу

   Книга = Эксель.WorkBooks.Open(ИмяФайла);

   Лист  = Книга.WorkSheets(НомерЛиста);

все равно не работает, та же ошибка.

Serginio1

39 — 08.11.12 — 15:31