1с чтение файла excel без excel - Word и Excel - помощь в работе с программами

Gorr

12.07.22 — 20:00

Нужно читать файлы екселя большого объема максимально быстро. Возможно ли установить эту библиотеку отдельно без ms office?

Lama12

1 — 12.07.22 — 20:11

Должна быть такая возможность.

NorthWind

2 — 12.07.22 — 20:13

(0) если речь про xls (не xlsx), то во всех виндах уже стоит. Если более современные форматы начиная с office 2007, то нужно поставить что-нибудь наподобие вот этого

https://www.microsoft.com/en-us/download/details.aspx?id=13255

но я бы советовал не мучиться. Если у вас 8.3… кажется 10 и старше, то там ТабличныйДокумент читает xls/xlsx нативно безо всякого ADO.

NorthWind

3 — 12.07.22 — 20:14

причем качество разборки формата вполне приличное, почти все умеет, если у вас не особо изысканное форматирование, то должен справиться.

youalex

4 — 12.07.22 — 20:23

Если есть мс скл, и конкретный файл — можно его (мс скл) задействовать. Например подключить файл-источник как связанный сервер и дальше дергать данные через ADO или даже ВИД (по идее должно работать, но не уверен).

https://docs.microsoft.com/ru-ru/sql/relational-databases/import-export/import-data-from-excel-to-sql?view=sql-server-ver15

Это если не подойдет нативный 1сный метод из (2))

Фрэнки

5 — 12.07.22 — 22:53

Нужно смотреть, что в этом большом объеме: большое количество данных, сложенных в один или несколько листов или это файл с некими сложными тяжеловесными элементами.

многостраничные xls/xlsx читаются.

kubik_live

6 — 12.07.22 — 23:54

(2) Была таблица с 3-мя листами,

Надо было прочитать только 1 лист (независимо от имени)

ТабличныйДокумент тупо прочитал все листы.

Отказался в сторону ADO.. или ЧЯНТД?

Фрэнки

7 — 13.07.22 — 01:09

(6) он прочитал тупо всё, потому что ты его тупо заставил читать всё.

ZDenis

8 — 13.07.22 — 01:10

(6) Там есть области, их можно перебирать, получать по имени или по индексу (это я о листах)

NorthWind

9 — 13.07.22 — 07:01

(6) Да, там есть нюансы. Дело в том, что табличный документ 1С не имеет такой сущности «лист». При чтении всегда зачитывается весь документ, и листы XLS/XLSX, если их более одного, конвертируются в именованные Области и располагаются в таблице сверху вниз в том же порядке, в котором листы были в исходном документе. Соответственно, выбрав область по имени листа и получив ее верхнюю левую строку, можно определить, где именно в документе она лежит. Но нужно иметь в виду, что имена областей в 1С должны удовлетворять правилам именования переменных, т.е. некоторые символы использовать нельзя, в частности пробелы. А листы в Excel таким правилам удовлетворять не обязаны, поэтому 1С при разборе меняет имена, заменяя негодные символы на «_». Это может создать некоторые сложности при поиске листов, если нужно, чтобы имена задавал пользователь программы.

NorthWind

10 — 13.07.22 — 08:17

если нужно прочитать только первый по счету лист, то получаете первую область и затем ее нижнюю строку. Соответственно, ваши данные — от первой строки до нижней, дальше вам не надо.

Kigo_Kigo

11 — 13.07.22 — 08:44

А если расширение XLSX заменить на zip то можно распаковать и там будут файлы в xml и уже читать их, но это так, такое вот извращение, видел у одной шибко «секретной конторе» :)))

6awkup_true

12 — 13.07.22 — 08:55

а можно не париться и воспользоваться построителем запроса. наличие экселя вообще не обязательно. имена колонок будут взяты по первой строке.

&НаКлиенте

Процедура ПрочитатьФайл(Команда)

АдресВременногоХранилища = ПоместитьВоВременноеХранилище(Новый ДвоичныеДанные(ПутьКФайлу), ЭтаФорма.УникальныйИдентификатор);

ПрочитатьФайлНаСервере(АдресВременногоХранилища);

КонецПроцедуры

&НаСервере

Процедура ПрочитатьФайлНомеровНаСервере(АдресВременногоХранилища)

БинДанные = ПолучитьИзВременногоХранилища(АдресВременногоХранилища);

    Если БинДанные <> Неопределено Тогда

        ИмяФайла = ПолучитьИмяВременногоФайла(«xlsx»);

        БинДанные.Записать(ИмяФайла);

    Иначе

        УдалитьФайлы(ИмяФайла);

        ВызватьИсключение «Проблемы с файлом»;

    КонецЕсли;

    ФайлНаДиске = Новый Файл(СокрЛП(ИмяФайла));

    Если Не ФайлНаДиске.Существует() Тогда

        Возврат;

    КонецЕсли;

    ТабличныйДокумент = Новый ТабличныйДокумент;

    ТабличныйДокумент.Очистить();

    ТабличныйДокумент.Прочитать(ИмяФайла);

    ПЗ = Новый ПостроительЗапроса;

    ПЗ.ИсточникДанных = Новый ОписаниеИсточникаДанных(ТабличныйДокумент.Область());

    ПЗ.ДобавлениеПредставлений = ТипДобавленияПредставлений.НеДобавлять;

    ПЗ.ЗаполнитьНастройки();

    ПЗ.Выполнить();

РезультатЧтения = ПЗ.Результат.Выгрузить();

КонецПроцедуры

NorthWind

13 — 13.07.22 — 09:20

(12) да, если у файла более-менее регулярная структура а-ля таблица БД, то это хороший вариант. Причем здесь тоже можно отфильтровать по конкретному листу (области) при желании.

lodger

14 — 13.07.22 — 09:22

(0) все способы работы с excel без тулз ms не отличаются молниеносной работой.

в 1с один из самых простых и быстрых вариантов — ТабличныйДокумент.Прочитать()

Gorr

15 — 13.07.22 — 09:40

Коллеги, добрый день! Благодарю за желание помочь!

Предполагается на входе плоский файл с заголовком и одним листом.

(2) Спасибо попробую!

(4) про вариант через ms sql спасибо не слышал. интересно.

Одним из важных критериев решения является скорость.

Так вот по скорости думается мне вариант чтения через АДО должен работать быстрее всего.

Скорость загрузки в приоритете.

6awkup_true

16 — 13.07.22 — 09:46

(15) в предложенном мной варианте файл экселя на 350К+ строк с 40+ колонками прочитался за чуть менее чем 2 секунды

Kassern

17 — 13.07.22 — 09:46

(0) Надеюсь вы понимаете, что чтение файла экселя — это лишь малая доля времени, львиную долю скушает анализ данных и запись в базу.

Kassern

18 — 13.07.22 — 09:47

поэтому особо париться чем прочитать я думаю не стоит, хоть АДО хоть таб док, хоть через ком.

Gorr

19 — 13.07.22 — 09:52

(16) Класс!

(17) Соглашусь.

Gorr

20 — 13.07.22 — 10:04

(2) заработало кстати!!!

NorthWind

21 — 13.07.22 — 12:32

(15) ну насчет «быстрее всего» у меня уверенности нет, потому что там прослойка достаточно тяжеловесная. Думаю, что самые быстрый вариант — это в (11), если применить какой-нибудь нересурсоемкий метод чтения XML, а на втором месте чтение через табличный документ. ADO, думаю, будет на третьем месте.

NorthWind

22 — 13.07.22 — 12:32

хотя, может, я и ошибаюсь

Источник

Чтение файла Excel в 1С 8.х может проводиться несколькими способами. Одним из самых простых способов программного чтения файлов Excel в 1С является подключение через COMобъект.

Перед тем как перейти к процедурам чтения файла Excel, нужно найти его адрес. Для этого удобно воспользоваться стандартным диалогом открытия файла. Нужно создать текстовое поле с достаточной длиной (адреса бывают длинные). В обработчике события НачалоВыбора нужно прописать следующую процедуру.

Процедура ФайлНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)
Диалог = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Открытие);
Диалог.ПредварительныйПросмотр = Ложь;
Диалог.Фильтр = «(*.xls)|*.xls»;

Если ЗначениеЗаполнено(Файл) Тогда
Диалог.ПолноеИмяФайла= Файл;
КонецЕсли;

Если Диалог.Выбрать() Тогда
Файл= Диалог.ПолноеИмяФайла;

КонецЕсли;

КонецПроцедуры

После этого в реквизите Файл должен находить полный адрес файла Excel.

Допустим, файл содержит две колонки:

Артикул.
Наименование товара.

Данные начинаются с 4 строки. Всего строк в файле 5000.

Процедура будет выглядеть так:

Процедура ИмпортироватьЛистФАдрес ()

Ехсел=Новый COMObject(«Excel.Application»);
Книга=Ехсел.Workbooks;
Книга.Open(Файл);

ТЗ=новый ТаблицаЗначений;
ТЗ.Колонки.Добавить(«Артикул»);
ТЗ.Колонки.Добавить(«Наименование»);
Для СчетчикЦикла=4 По 5000 Цикл

НоваяСтрока=ТЗ.Добавить();
НоваяСтрока.Артикул=СокрЛП(Ехсел.Cells(СчетчикЦикла,1).value);
НоваяСтрока.Наименование=СокрЛП(Ехсел.Cells(СчетчикЦикла,2).value);
КонецЦикла;

Ехсел.Application.Quit(); // Если этого не сделать, процесс EXCEL останется в памяти

КонецПроцедуры

Пустые ячейки файла Excel имеют значение Неопределено. Поэтому, если количество строк в файле заранее не известно, но есть уверенность, что записи идут одна за другой и не прерываются пустыми строками, то процедуру можно модифицировать так.

Процедура ИмпортироватьЛистФАдрес ()

Ехсел=Новый COMObject(«Excel.Application»);
Книга=Ехсел.Workbooks;
Книга.Open(Файл);

ТЗ=новый ТаблицаЗначений;
ТЗ.Колонки.Добавить(«Артикул»);
ТЗ.Колонки.Добавить(«Наименование»);

СчетчикЦикла=4;

Пока СокрЛП(Ехсел.Cells(СчетчикЦикла,1).value)<>Неопределено Цикл

КонецЦикла;

Ехсел.Application.Quit(); // Если этого не сделать, процесс EXCEL останется в памяти

КонецПроцедуры

Кроме того, можно определить количество строк в файле Excel. Это делается так:

Версия = Лев(Ехсел.Version,Найти(Ехсел.Version,«.»)—1);
Если Версия = «8» тогда
ФайлСтрок = Ехсел.Cells.CurrentRegion.Rows.Count;
ФайлКолонок = Макс(Ехсел.Cells.CurrentRegion.Columns.Count, 13);
Иначе
ФайлСтрок = Ехсел.Cells(1,1).SpecialCells(11).Row;
ФайлКолонок = Ехсел.Cells(1,1).SpecialCells(11).Column;
Конецесли;

После этого можно применять полученные значения количества строк и колонок в коде, аналогичном описанному выше.

Процедура ИмпортироватьЛистФАдрес ()

Ехсел=Новый COMObject(«Excel.Application»);
Книга=Ехсел.Workbooks;
Книга.Open(Файл);

Если Версия = «8» тогда
ФайлСтрок = Ехсел.Cells.CurrentRegion.Rows.Count;
ФайлКолонок = Макс(Ехсел.Cells.CurrentRegion.Columns.Count, 13);
Иначе
ФайлСтрок = Ехсел.Cells(1,1).SpecialCells(11).Row;
ФайлКолонок = Ехсел.Cells(1,1).SpecialCells(11).Column;
Конецесли;

ТЗ=новый ТаблицаЗначений;
ТЗ.Колонки.Добавить(«Артикул»);
ТЗ.Колонки.Добавить(«Наименование»);
Для СчетчикЦикла=4 По ФайлСтрок Цикл

Ехсел.Application.Quit(); // Если этого не сделать, процесс EXCEL останется в памяти

КонецПроцедуры

Источник

Весьма частая задача, с которой сталкивается 1С разработчик – это чтение файлов Excel и загрузка их в 1С. Есть как минимум два способа прочитать файл Excel – средствами платформы 1С, или используя COM-объект приложения MS Excel. В статье рассматривается чтение файлов xls, xlsx при помощи табличного документа.

Содержание

Общая информация

В платформе 1С 8 существует объект ТабличныйДокумент, который позволяет формировать и выводить на экран печатные формы в табличном виде. Но у табличного документа есть еще одно применение – чтение данных из табличных файлов. Поддерживаются форматы xls, xlsx и ods. Т.е. можно загружать табличные файлы, созданные в пакете MS Office или OpenOffice Calc.

Значения типа Число или Дата, содержащиеся в ячейках исходного табличного файла, можно считать двумя способами – как значение, либо как текст. Рассмотрим пример: пусть в ячейке содержится число 123,456, и установлен формат с округлением до целого числа; в этом случае отображаться будет текст “123”, а значение будет храниться 123,456

Если прочитать с указанием способа чтения как “Значение”, в табличный документ 1С будет прочитано исходное значение 123,456
Если прочитать с указанием способа чтения как “Текст”, значение будет потеряно, и в табличный документ прочитается текст “123”

Использование объекта ВременноеХранилище

Вспомогательные процедуры — диалог выбора файла

Следующий код не является обязательным для решения задачи – путь к исходному файлу можно указать в коде, ввести вручную, скопировать из адресной строки ОС или прочитать из БД – вариантов очень много. Мы же рассмотрим пример, когда пользователь сам указывает файл на клиентском компьютере, и путь к этому файлу помещается в реквизит. В примере будем использовать реквизит формы ПутьКФайлу

Создадим обработчик события НачалоВыбора:

&НаКлиенте
Процедура ПутьКФайлуНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)
	
	СтандартнаяОбработка = Ложь;
	ВыбратьФайлНаКлиенте();
	
КонецПроцедуры

Для того чтобы код был универсальным, и работал в случае отказа от модальных синхронных методов, нам понадобится создать асинхронную процедуру ВыбратьФайлНаКлиенте(). В ней мы создаем диалог выбора для открытия файла, указываем фильтр с нужными форматами – xls и xlsx, а также отключаем множественный выбор файлов. Перед методом ВыбратьАсинх добавляем ключевое слово Ждать, с тем чтобы дальнейший код дождался возвращаемого значения.

&НаКлиенте
Асинх Процедура ВыбратьФайлНаКлиенте()
	
	Перем Диалог;
	
	Диалог = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Открытие);
	Диалог.Фильтр = "Excel файлы(*.xls;*.xlsx)|*.xls;*.xlsx";
	Диалог.ИндексФильтра = 0;
	Диалог.ПредварительныйПросмотр = Ложь;
	Диалог.МножественныйВыбор = Ложь; 
	РезультатВыбора = Ждать Диалог.ВыбратьАсинх();
	Если РезультатВыбора <> Неопределено Тогда
		ПутьКФайлу = РезультатВыбора[0];
	КонецЕсли;
	
КонецПроцедуры

Двоичные данные во временное хранилище

Логика кода будет следующая. Нам понадобятся двепроцедуры – клиентский обработчик команды, и серверный метод который и будет непосредственно считывать переданный файл.

Клиентский код:

проверяем, указан ли путь к файлу. Если не указан – прекращаем выполнение
Получаем двоичные данные из файла по указанному пути
Помещаем эти двоичные данные во временное хранилище
Далее передаем на сервер адрес этого временного хранилища

&НаКлиенте
Процедура ДвоичныеДанныеВоВременноеХранилище(Команда)

	Если Не ЗначениеЗаполнено(ПутьКФайлу) Тогда
		Возврат;
	КонецЕсли;
	
	ДД = Новый ДвоичныеДанные(ПутьКФайлу);
	АдресВХ = ПоместитьВоВременноеХранилище(ДД);
	ПрочитатьИзВХНаСервере(АдресВХ);
	
КонецПроцедуры

Серверный код:

Создаем временный файл с нужным расширением (в примере – xlsx)
Получаем двоичные данные из временного хранилища
Записываем во временный файл
Определяем вариант чтения файла – читать значения табличного документа как текст, или как значения
Далее используем метод Прочитать, и считываем из временного файла данные в табличный документ

Метод Прочитать лучше делать в попытке, и отдельно продумать и написать код обработки исключения. для упрощения примера мы это исключение никак не обрабатываем. В случае, если передан поврежденный файл, или его невозможно прочитать по какой-то другой причине, он просто не считается в табличный документ.

&НаСервере
Процедура ПрочитатьИзВХНаСервере(АдресВХ, Режим = "Значение")
	
	ИмяВременногоФайла = ПолучитьИмяВременногоФайла("xlsx");
	
	ДД = ПолучитьИзВременногоХранилища(АдресВХ);
	ДД.Записать(ИмяВременногоФайла);

	Если Режим = "Текст" Тогда
		СпособЧтения = СпособЧтенияЗначенийТабличногоДокумента.Текст;
	Иначе
		СпособЧтения = СпособЧтенияЗначенийТабличногоДокумента.Значение;
	КонецЕсли;

	Попытка
		ТабДок.Прочитать(ИмяВременногоФайла, СпособЧтения);
	Исключение
	КонецПопытки;	
	
КонецПроцедуры

Рассмотренный пример является достаточно универсальным – процедуру ПрочитатьИзВХНаСервере() можно использовать с любыми двоичными данными, помещенными во временное хранилище. Это могут быть двоичные данные, полученные с веб-сервиса, считанные из базы данных, полученные из макета, созданного в конфигураторе – код от этого не изменится.

Помещение файла на сервер в 1С

Более простой, но менее универсальный способ, предназначенный исключительно для передачи файла с клиента на сервер – это использование метода НачатьПомещениеФайлаНаСервер. В платформе предусмотрено несколько методов для помещения файлов – как одиночных, так и нескольких одновременно. Эти методы делятся на синхронные и асинхронные. Начиная с версии 8.3.18 появились методы, использующие ключевые слова Асинх и Ждать. Аналогичный метод мы рассмотрели при работе с диалогом. Далее разберем “классический” вариант с обработкой оповещения.

Логика кода следующая:

Создаем описание оповещения и указываем в нем процедуру, которая будет вызвана после окончания помещения файла на сервер
Указываем параметры диалога выбора файла и добавляем фильтр
Вызываем помещение файла на сервер
После того как файл помещен во временное хранилище, используем ту же процедуру, которую мы реализовали в первом примере – ПрочитатьИзВХНаСервере. В этом примере мы для разнообразия используем способ чтения значений как “Текст”.

&НаКлиенте
Процедура ПередачаФайла(Команда)
	
ОбработкаОкончанияПомещения = Новый ОписаниеОповещения("ОбработчикОкончанияПомещения", ЭтотОбъект);
ПараметрыДиалога = Новый ПараметрыДиалогаПомещенияФайлов;
ПараметрыДиалога.Фильтр = "Excel файлы(*.xls;*.xlsx)|*.xls;*.xlsx";
НачатьПомещениеФайлаНаСервер(ОбработкаОкончанияПомещения, , , АдресВХ, ПараметрыДиалога, ЭтотОбъект.УникальныйИдентификатор);
	
КонецПроцедуры

&НаКлиенте
Процедура ОбработчикОкончанияПомещения(ОписаниеПомещенногоФайла, ДополнительныеПараметры) Экспорт
	
АдресФайла = ОписаниеПомещенногоФайла.Адрес;
ПрочитатьИзВХНаСервере(АдресФайла, "Текст");
	
КонецПроцедуры

Использование потока для чтения файла

В случае, если нам нужно просто передать файл с клиента на сервер для сохранения в базу данных, либо мы хотим прочитать файл в формате ods(Open Documents Spreadsheet) или mxl(встроенный формат табличных документов 1С), мы можем воспользоваться еще одним способом – с использованием потоков данных.

В этом случае нам не понадобится создавать временный файл и следить за его корректным удалением. Код будет очень похож на прерыдущий пример. Мы также выбираем файл с использованием метода НачатьПомещениеФайлаНаСервер, но указываем другой фильтр. А в обработчике оповещения вызываем серверную процедуру ПрочитатьВПоток. В методе Прочитать() нам нужно явным образом указать тип файла табличного документа, который мы считываем.

&НаКлиенте
Процедура ПрочитатьЧерезПоток(Команда)

ОбработкаОкончанияПомещения = Новый ОписаниеОповещения("ОбработчикОкончанияПомещенияПоток", ЭтотОбъект);
ПараметрыДиалога = Новый ПараметрыДиалогаПомещенияФайлов;
ПараметрыДиалога.Фильтр = "файлы ODS или MXL|*.ods;*.mxl";

НачатьПомещениеФайлаНаСервер(ОбработкаОкончанияПомещения, , , АдресВХ, ПараметрыДиалога, ЭтотОбъект.УникальныйИдентификатор);

КонецПроцедуры

&НаКлиенте
Процедура ОбработчикОкончанияПомещенияПоток(ОписаниеПомещенногоФайла, ДополнительныеПараметры) Экспорт

АдресФайла = ОписаниеПомещенногоФайла.Адрес;
ПрочитатьВПоток(АдресФайла);

КонецПроцедуры

&НаСервере
Процедура ПрочитатьВПоток(АдресФайла)

ДД = ПолучитьИзВременногоХранилища(АдресФайла);
Поток = ДД.ОткрытьПотокДляЧтения();
ТабДок.Прочитать(Поток,,ТипФайлаТабличногоДокумента.ODS);
Поток.Закрыть();

КонецПроцедуры

Надеюсь, рассмотренные примеры помогут вам справиться с задачей передать файл с клиента на сервере и прочитать файл Excel в 1С.

Источник

На чтение 9 мин Просмотров 26.4к. Опубликовано 09.11.2017

MS Excel давно стал стандартом для работы с электронными таблицами. В статье рассматриваются способы программной выгрузки и загрузки из 1С в файлы Excel.

Существует несколько способов программной работы с файлами Excel из 1С. Каждый из них имеет свои преимущества и недостатки.

Содержание

Обмен через табличный документ
Обмен через OLE
Использование COMSafeArray
Обмен через ADO
Выгрузка без программирования

Обмен через табличный документ

Данный способ простой. Его суть заключается в том, что объект ТабличныйДокумент имеет методы:

Записать(<ИмяФайла>, <ТипФайлаТаблицы>) для выгрузки данных в файл;
Прочитать(<ИмяФайла>, <СпособЧтенияЗначений>) для загрузки данных из файла.

Внимание!

Метод Записать() доступен как на клиенте, так и на сервере. Метод Прочитать() доступен только на стороне сервера. Необходимо помнить об этом
при планировании клиент-серверного взаимодействия.

Рассмотрим пример сохранения табличного документа в файл. Необходимо любым способом создать и заполнить объект ТабличныйДокумент, а выгрузка в файл осуществляется всего лишь одной строкой:

ТабДок.Записать(ПутьКФайлу, ТипФайлаТабличногоДокумента.XLSX);

Здесь ТабДок — сформированный табличный документ, ПутьКФайлу — имя файла для выгрузки, ТипФайлаТабличногоДокумента.XLSX — формат создаваемого файла. Поддерживаются следующие форматы Excel:

XLS95 — формат Excel 95;
XLS97 — формат Excel 97;
XLSX — формат Excel 2007.

Загрузка из файла осуществляется также достаточно просто:

ТабДок = Новый ТабличныйДокумент;
ТабДок.Прочитать(ПутьКФайлу, СпособЧтенияЗначенийТабличногоДокумента.Значение);

Здесь ПутьКФайлу — путь к загружаемому файлу Excel. СпособЧтенияЗначенийТабличногоДокумента.Значение определяет, каким образом нужно интерпретировать данные, считываемые из исходного документа. Доступны варианты:

Значение;
Текст.

Обмен через OLE

Обмен через технологию OLE automation, пожалуй, самый распространенный вариант программной работы с файлами Excel. Он позволяет использовать весь функционал, предоставляемый Excel, но отличается медленной скоростью работы по сравнению с другими способами. Для обмена через OLE требуется установка MS Excel:

На компьютере конечного пользователя, если обмен происходит на стороне клиента;
На компьютере сервера 1С:Предприятие, если обмен происходит на стороне сервера.

Пример выгрузки:

// Создание COM-объекта
Эксель = Новый COMОбъект(«Excel.Application»);
// Отключение вывода предупреждений и вопросов
Эксель.DisplayAlerts = Ложь;
// Создание новой книги
Книга = Эксель.WorkBooks.Add();
// Позиционирование на первом листе
Лист = Книга.Worksheets(1);

// Запись значения в ячейку
Лист.Cells(НомерСтроки, НомерКолонки).Value = ЗначениеЯчейки;

// Сохранение файла
Книга.SaveAs(ИмяФайла);

// Закрытие Эксель и освобождение памяти
Эксель.Quit();
Эксель = 0;

Примеры чтения:

// —— ВАРИАНТ 1 ——

// Создание COM-объекта
Эксель = Новый COMОбъект(«Excel.Application»);
// Открытие книги
Книга = Эксель.Workbooks.Open(ПутьКФайлу);
// Позиционирование на нужном листе
Лист = Книга.Worksheets(1);

// Чтение значения ячейки, обычно здесь располагается цикл обхода ячеек
ЗначениеЯчейки = Лист.Cells(НомерСтроки, НомерКолонки).Value;

// Закрытие книги
Книга.Close(0);

// Закрытие Эксель и освобождение памяти
Эксель.Quit();
Эксель = 0;

// —— ВАРИАНТ 2 ——

// Открытие книги
Книга = ПолучитьCOMОбъект(ПутьКФайлу);
// Позиционирование на нужном листе
Лист = Книга.Worksheets(1);

// Чтение значения ячейки, обычно здесь располагается цикл обхода ячеек
ЗначениеЯчейки = Лист.Cells(НомерСтроки, НомерКолонки).Value;

// Закрытие книги
Книга.Application.Quit();

Для обхода всех заполненных строк листа Excel можно использовать следующие приемы:

// —— ВАРИАНТ 1 ——
КоличествоСтрок = Лист.Cells(1, 1).SpecialCells(11).Row;
Для НомерСтроки = 1 По КоличествоСтрок Цикл
ЗначениеЯчейки = Лист.Cells(НомерСтроки, НомерКолонки).Value;
КонецЦикла;

// —— ВАРИАНТ 2 ——
НомерСтроки = 0;
Пока Истина Цикл
НомерСтроки = НомерСтроки + 1;
ЗначениеЯчейки = Лист.Cells(НомерСтроки, НомерКолонки).Value;
Если НЕ ЗначениеЗаполнено(ЗначениеЯчейки) Тогда
Прервать;
КонецЕсли;
КонецЦикла;

Вместо последовательного обхода всех строк листа можно выгрузить все данные в массив и работать с ним. Такой подход будет быстрее при чтении большого объема данных:

ВсегоКолонок = Лист.Cells(1, 1).SpecialCells(11).Column;
ВсегоСтрок = Лист.Cells(1, 1).SpecialCells(11).Row;

Область = Лист.Range(Лист.Cells(1, 1), Лист.Cells(ВсегоСтрок, ВсегоКолонок));
Данные = Область.Value.Выгрузить();

В таблице ниже приведены наиболее востребованные свойства и методы для работы с Excel через OLE:

Действие	Код	Комментарий
Работа с приложением
Установка видимости окна приложения	Эксель.Visible = Ложь;
Установка режима вывода предупреждений (выводить/не выводить)	Эксель.DisplayAlerts = Ложь;
Закрытие приложения	Эксель.Quit();
Работа с книгой
Создание новой книги	Книга = Эксель.WorkBooks.Add();
Открытие существующей книги	Книга = Эксель.WorkBooks.Open(ИмяФайла);
Сохранение книги	Книга.SaveAs(ИмяФайла);
Закрытие книги	Книга.Close(0);
Работа с листом
Установка текущего листа	Лист = Книга.WorkSheets(НомерЛиста);
Установка имени	Лист.Name = Имя;
Установка защиты	Лист.Protect();
Снятие защиты	Лист.UnProtect();
Установка ориентации страницы	Лист.PageSetup.Orientation = 2;	1 — книжная, 2 — альбомная
Установка левой границы	Лист.PageSetup.LeftMargin = Эксель.CentimetersToPoints(Сантиметры);
Установка верхней границы	Лист.PageSetup.TopMargin = Эксель.CentimetersToPoints(Сантиметры);
Установка правой границы	Лист.PageSetup.RightMargin = Эксель.CentimetersToPoints(Сантиметры);
Установка нижней границы	Лист.PageSetup.BottomMargin = Эксель.CentimetersToPoints(Сантиметры);
Работа со строками, колонками, ячейками
Установка ширины колонки	Лист.Columns(НомерКолонки).ColumnWidth = Ширина;
Удаление строки	Лист.Rows(НомерСтроки).Delete();
Удаление колонки	Лист.Columns(НомерКолонки).Delete();
Удаление ячейки	Лист.Cells(НомерСтроки, НомерКолонки).Delete();
Установка значения	Лист.Cells(НомерСтроки, НомерКолонки).Value = Значение;
Объединение ячеек	Лист.Range(Лист.Cells(НомерСтроки, НомерКолонки), Лист.Cells(НомерСтроки1, НомерКолонки1)).Merge();
Установка шрифта	Лист.Cells(НомерСтроки, НомерКолонки).Font.Name = ИмяШрифта;
Установка размера шрифта	Лист.Cells(НомерСтроки, НомерКолонки).Font.Size = РазмерШрифта;
Установка жирного шрифта	Лист.Cells(НомерСтроки, НомерКолонки).Font.Bold = 1;	1 — жирный шрифт, 0 — нормальный
Установка курсива	Лист.Cells(НомерСтроки, НомерКолонки).Font.Italic = 1;	1 — курсив, 0 — нормальный
Установка подчеркнутого шрифта	Лист.Cells(НомерСтроки, НомерКолонки).Font.Underline = 2;	2 — подчеркнутый, 1 — нет

Для того, чтобы узнать какое свойство нужно менять или какой метод вызвать можно воспользоваться макросами Excel. Если записать макрос с требуемыми действиями, то после можно посмотреть программный код на VBA записанного макроса.

Использование COMSafeArray

При выгрузке больших объемов данных из 1С в Excel для ускорения можно использовать объект COMSafeArray. Согласно определению из синтакс-помощника, COMSafeArray — объектная оболочка над многомерным массивом SafeArray из COM. Позволяет создавать и использовать SafeArray для обмена данными между COM-объектами. Проще говоря, это массив значений, который можно использовать для обмена между приложениями по технологии OLE.

// Создание COMSafeArray
МассивКом = Новый COMSafeArray(«VT_Variant», ВсегоКолонок, ВсегоСтрок);
// Заполнение COMSafeArray
Для Стр = 0 По ВсегоСтрок — 1 Цикл
Для Кол = 0 По ВсегоКолонок — 1 Цикл
МассивКом.SetValue(Кол, Стр, Значение);
КонецЦикла;
КонецЦикла;
// Присвоение области листа Excel значений из COMSafeArray
Лист.Range(Лист.Cells(1, 1), Лист.Cells(ВсегоСтрок, ВсегоКолонок)).Value = МассивКом;

Обмен через ADO

Файл Excel при обмене через ADO представляет собой базу данных, к которой можно обращаться при помощи SQL-запросов. Установка MS Excel не требуется, но обязательно наличие драйвера ODBC, при помощи которого будет осуществляться доступ. Используемый драйвер ODBC определяется при указании строки соединения к файлу. Обычно требуемый драйвер уже установлен на компьютере.

Обмен через ADO заметно быстрее обмена через OLE, но при выгрузке нет возможности использовать функционал Excel для оформления ячеек, разметки страниц, задания формул и т.д.

Пример выгрузки:

// Создание COM-объекта для соединения
Соединение = Новый COMОбъект(«ADODB.Connection»);

// Установка строки соединения
Соединение.ConnectionString = «
|Provider=Microsoft.ACE.OLEDB.12.0;
|Data Source=»+ИмяФайла+«;
|Extended Properties=»»Excel 12.0 XML;HDR=YES»»;»;
Соединение.Open(); // Открытие соединения

// Создание COM-объекта для команды
Команда = Новый COMОбъект(«ADODB.Command»);
Команда.ActiveConnection = Соединение;

// Присвоение текста команды для создания таблицы
Команда.CommandText = «CREATE TABLE [Лист1] (Колонка1 char(255), Колонка2 date, Колонка3 int, Колонка4 float)»;
Команда.Execute(); // Выполнение команды

// Присвоение текста команды для добавления строки таблицы
Команда.CommandText = «INSERT INTO [Лист1] (Колонка1, Колонка2, Колонка3, Колонка4) values (‘абвгдеё’, ‘8/11/2017’, ‘12345’, ‘12345,6789’)»;
Команда.Execute(); // Выполнение команды

// Удаление команды и закрытие соединения
Команда = Неопределено;
Соединение.Close();
Соединение = Неопределено;

Для создания нового листа и формирования его структуры можно воспользоваться объектами ADOX.Catalog и ADOX.Table. В этом случае код примет вид:

// Создание COM-объекта для работы с книгой
Книга = Новый COMОбъект(«ADOX.Catalog»);
Книга.ActiveConnection = Соединение;

// Создание COM-объекта для работы со структурой данных на листе
Таблица = Новый COMОбъект(«ADOX.Table»);
Таблица.Name = «Лист1»;
Таблица.Columns.Append(«Колонка1», 202);
Таблица.Columns.Append(«Колонка2», 7);
Таблица.Columns.Append(«Колонка3», 5);
Таблица.Columns.Append(«Колонка4», 5);

// Создание в книге листа с описанной структурой
Книга.Tables.Append(Таблица);
Таблица = Неопределено;
Книга = Неопределено;

В приведенном примере в методе

Таблица.Columns.Append(«Колонка1», 202);

во втором параметре указывается тип колонки. Параметр необязательный, вот некоторые значения типа колонки:

5 — adDouble;
6 — adCurrency;
7 — adDate;
11 — adBoolean;
202 — adVarWChar;
203 — adLongVarWChar.

Пример чтения:

// Создание COM-объекта для соединения
Соединение = Новый COMОбъект(«ADODB.Connection»);

// Установка строки соединения
Соединение.ConnectionString = «
|Provider=Microsoft.ACE.OLEDB.12.0;
|Data Source=»+ИмяФайла+«;
|Extended Properties=»»Excel 12.0 XML;HDR=YES»»;»;
Соединение.Open(); // Открытие соединения

// Создание COM-объекта для получения выборки
Выборка = Новый COMОбъект(«ADODB.Recordset»);
ТекстЗапроса = «SELECT * FROM [Лист1$]»;

// Выполнение запроса
Выборка.Open(ТекстЗапроса, Соединение);

// Обход результата выборки
Пока НЕ Выборка.EOF() Цикл
ЗначениеКолонки1 = Выборка.Fields.Item(«Колонка1»).Value; // Обращение по имени колонки
ЗначениеКолонки2 = Выборка.Fields.Item(0).Value; // Обращение по индексу колонки
Выборка.MoveNext();
КонецЦикла;

Выборка.Close();
Выборка = Неопределено;
Соединение.Close();
Соединение = Неопределено;

В строке соединения параметр HDR определяет как будет восприниматься первая строка на листе. Возможны варианты:

YES — первая строка воспринимается как названия колонок. К значениям можно обращаться по имени и по индексу колонки.
NO — первая строка воспринимается как данные. К значениям можно обращаться только по индексу колонки.

В приведенных примерах рассмотрено лишь несколько объектов ADO. Объектная модель ADO состоит из следующих объектов:

Connection;
Command;
Recordset;
Record;
Fields;
Stream;
Errors;
Parameters;
Properties.

Выгрузка без программирования

Для сохранения данных из 1С в Excel не всегда целесообразно прибегать к программированию. Если в режиме Предприятия пользователь может отобразить требуемые для выгрузки данные, то, их возможно сохранить в Excel без программирования.

Для сохранения табличного документа (например, результата отчета) можно вызвать команду Сохранить или Сохранить как… главного меню.

В открывшемся окне требуется выбрать каталог, имя и формат сохраняемого файла.

Для сохранения данных динамических списков (например, списка номенклатуры) необходимо:

Вывести данные в табличный документ при помощи команды Еще ⇒ Вывести список…;
Сохранить табличный документ в требуемый формат.

Источник

&НаКлиенте
Процедура ФайлНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка) //необходимо в событии «НачалоВыбора» поля ввода вызвать ДиалогВыбораФайлаДиалог = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Открытие);
Диалог.Заголовок = «Выберите файл Excel»;
Диалог.ПредварительныйПросмотр = Ложь;
Диалог.Фильтр = «(*.xls,*.xlsx)|*.xls;*.xlsx;|Microsoft Excel 97/2000/XP/2003 (*.xls)|*.xls|Microsoft Excel 2007/2010 (*.xlsx)|*.xlsx»;

Если

ЗначениеЗаполнено(Объект.Файл) Тогда
Диалог.ПолноеИмяФайла= Объект.Файл;
КонецЕсли;

Если

Диалог.Выбрать() Тогда
ВыбранныйФайл = Диалог.ПолноеИмяФайла;
Объект.Файл = ВыбранныйФайл;
ЧтениеExcel_через_ТД(ВыбранныйФайл);
КонецЕсли;

КонецПроцедуры

&НаСервере
Процедура ЧтениеExcel_через_ТД(ВыбранныйФайл)//1) Выводим Excel в табличн.документ
ТаблДок = Новый ТабличныйДокумент;
ТаблДок.Прочитать(ВыбранныйФайл, СпособЧтенияЗначенийТабличногоДокумента.Значение);//2) Выгружаем в таблицу значений
ПЗ = Новый ПостроительЗапроса;
ПЗ.ИсточникДанных = Новый ОписаниеИсточникаДанных(ТаблДок.Область());
ПЗ.ДобавлениеПредставлений = ТипДобавленияПредставлений.НеДобавлять;
ПЗ.ЗаполнитьНастройки();
ПЗ.Выполнить();ТаблицаЗначений = ПЗ.Результат.Выгрузить();

КонецПроцедуры

Источник